Beschrijving

Intended to replace en:File:Parabola_in_projective_space.png, which is in a raster format.

Made in gnuplot. The code:

#!/usr/bin/gnuplot -persist

set parametric
set urange  [-0.9999:0.9999]
set vrange [-1:1]
set isosamples 25, 25

set xrange [-2:2]
set yrange [-2:2]
set zrange [-1:1]

set style line 1 lt rgb "#dddddd" lw 1
set style line 2 lt rgb "#9999ff" lw 1
set style line 3 lt rgb "#0000ff" lw 1
set style line 4 lt rgb "#ff9999" lw 1
set style line 5 lt rgb "#ff0000" lw 1

set border 15 ls 1
unset key
set noxtics
set noytics
set noztics

set view 55, 25
set terminal svg

# For scaling [-1:1] to [-∞:∞]
scale(x) = (x/((1-x)*(1+x)))

splot cos(u*pi)*cos(v*pi), sin(u*pi)*cos(v*pi), sin(v*pi) ls 1, \
      (u*2),(u*2)**2,-1 ls 2, \
      scale(u)/sqrt(scale(u)**2+scale(u)**4+1), scale(u)**2/sqrt(scale(u)**2+scale(u)**4+1), -1/sqrt(scale(u)**2+scale(u)**4+1) ls 3, \
      -scale(u)/sqrt(scale(u)**2+scale(u)**4+1), -scale(u)**2/sqrt(scale(u)**2+scale(u)**4+1), 1/sqrt(scale(u)**2+scale(u)**4+1) ls 3, \
      (u*2),(u*2)**3,-1 ls 4, \
      scale(u)/sqrt(scale(u)**2+scale(u)**6+1), scale(u)**3/sqrt(scale(u)**2+scale(u)**6+1), -1/sqrt(scale(u)**2+scale(u)**6+1) ls 5, \
      -scale(u)/sqrt(scale(u)**2+scale(u)**6+1), -scale(u)**3/sqrt(scale(u)**2+scale(u)**6+1), 1/sqrt(scale(u)**2+scale(u)**6+1) ls 5

Then the svg was cropped by changing the output to contain this line:

<svg width="600" height="600" viewBox="145 130 310 280"

Licentie

Ik, de auteursrechthebbende van dit werk, geef dit werk vrij in het publieke domein. Dit is wereldwijd van toepassing. In sommige landen is dit wettelijk niet mogelijk; in die gevallen geldt: Ik sta iedereen toe dit werk voor eender welk doel te gebruiken, zonder enige voorwaarden, tenzij zulke voorwaarden door de wet worden voorgeschreven.